Здравствуйте, angel.nero.
Это несложное задание. На будущее совет - не помещайте два вопроса в одну форму. Трудно делить.
Я, поскольку Вам нужны подпрограммы, все поместил в одну программу вместе с небольшими комментариями
Одно только, для второго задания сделал не процедуру, а функцию, которая возвращает результат логического типа.
Сами посудите: угол = 90[$186$], а гипотенуза (противоположная сторона) короче катета (прилежащая сторона)

Пример окна окна программы:

Приложение:
function CalcCount(n: Integer): Integer;
var sum, i, j: Integer;
count: Integer;
begin
count := 0;
for i:= 100 to 999 do begin
sum := 0;
j:=i;
while j > 0 do begin
sum := sum + j mod 10;
j := j div 10;
end;
if sum = n then inc(count)
end;
CalcCount := count
end;

{Хотя просили процедуру, написал функцию - возвращает результат =
можно ли построить. Пример: прямой угол, но противоположная сторона
(гипотенуза) задана меньше прилежащей (катет)}

{Угол задается в градусах}
function GetTriangle(angle1, len_opposite, len_another: Real;
VAR len, angle2, angle3: Real): Boolean;
begin
{Для вычислений используется теорема синусов. Помните её?}
{Сначала угол - а вдруг он задан больше 360 градусов?
Первым делом сохраним знак углаю. Так проще будет}
if angle1 > 0 then len :=1 else len :=-1;
angle1 := abs(angle1);
while angle1 > 360 do angle1 := angle1 - 360;
angle1 := angle1 * len;

GetTriangle := False;
angle1 := angle1*pi/180; {Переводим в радианы}
{Найдем угол напротив заданной стороны - потом с его помощью и нужный}
{Сначала синус угла}
angle2 := len_another*sin(angle1)/len_opposite;
{Вот проверка на существование! Синус по модулю не может быть больше 1}
if abs(angle2) > 1 then Exit; {Результат уже установлен = FALSE,
просто выходим}
{Особый случай angle = 1. Это, собственно, не прямоуголник, а прямая.
Но ведь может быть задано!}
if angle2 = 1 then angle2 := pi/2
else if angle2 = - 1 then angle2 := - pi/2
else angle2 := arctan(angle2/sqrt(1 - angle2*angle2));
{Третий угол найдем из условия, что сумма углов в треугольнике равна
180 градусов. У нас углы в радианах, значит pi}
angle3 := pi - angle1 - angle2;
{Длину третьей стороны через найденный угол и теорему синусов}
len := len_opposite*sin(angle3)/sin(angle1);
{Теперь в градусы}
angle2 := angle2*180/pi;
angle3 := angle3*180/pi;
{И сигнал о том, что все нормально}
GetTriangle := True
end;

var
Cnt: Integer;
alpha, betta, gamma, a, b, c: Real;
BEGIN
repeat
Write('Введите целое число от 1 до 27: '); ReadLn(Cnt);
if (Cnt < 1) or (Cnt > 27) then
Writeln('Неверный ввод. Попробуйте ещё раз');
until (Cnt >= 1) and (Cnt <= 27);
WriteLn('Число трехзначных чисел, сумма цифр которого равна ',Cnt,
' равно ',CalcCount(Cnt));
alpha := 90;
a := 5;
b := 4;
if GetTriangle(alpha, a, b, c, betta, gamma) then
WriteLn('c = ', c:10:2,', betta = ', betta:4:2,', gamma = ', gamma:4:2);
END.