Здравствуйте, Костин Александр Владимирович!

Программа в приложении.
Ваша основная ошибка, это не настроенные сегментные регистры.

;настраиваем сегмент данных
mov ax,@data
mov ds,ax

При запуске программы сегментные регистры DS и ES указывают на префикс программы, а не на сегмент данных.
Для функций ввода/вывода строки нужно:

AH = 09h
DS:DX -> '$'-terminated string

Удачи!

Приложение:
model small
.data
dbErrorNumber db 10,13,'wrong number$'
dbEnter db 10,13,'Enter number '
dbSimbol db 'A :$'
.stack 256
.code
.186
;текстовый режим
begin: mov ax,3
int 10h
;настраиваем сегмент данных
mov ax,@data
mov ds,ax
;вводим первое число
call inputNumber
push di
;вводим второе число
call inputNumber
;переводим строку
mov al,13
int 29h
mov al,10
int 29h
;проверяем число
pop ax
cmp ax,di
jb noError
;ошибка
isError: mov dx,offset dbErrorNumber
mov ah,9
int 21h
jmp doStop
;нет ошибки работаем
noError: call outputNumber
inc ax
cmp ax,di
jbe noError
;
;выход
doStop: xor ax,ax
int 16h
mov ax,4c00h
int 21h
;
;
;
;п\п-мма ввода числа
inputNumber: mov ah,9
mov dx,offset dbEnter
int 21h
;сбрасываем в число
xor di,di
;система счисления
mov si,10
;вводим без эхо
inputChar: xor ax,ax
int 16h
;клавиша ввод
cmp al,13
jz isStop
;диапозон цифровых клавиш
cmp al,'0'
jb inputChar
cmp al,'9'
ja inputChar
;да - выводим
int 29h
;переводим в число
and ax,0fh
;DI*10 + AX
xchg ax,di
xor dx,dx
mul si
add di,ax
jnc inputChar
pop cx
jmp isError
;меняем букву
isStop: inc byte ptr dbSimbol
ret
;
;
;
;выводим число
outputNumber: pusha
;начальные значения
mov si,10
xor cx,cx
;получаем остаток от деления и запоминаем в стеке
isDiv: xor dx,dx
div si
push dx
inc cx
;пока АХ не 0
or ax,ax
jnz isDiv
;выводим из стека
isout: pop ax
or ax,30h
int 29h
loop isOut
;разделительный пробел
mov al,' '
int 29h
popa
ret
end begin