Здравствуйте, Сергей!
Т.к. в данном примере число исходных данных ровно столько, сколько надо,
то проверка на 16 байт отсутствует. Это легко добавляется.
Демонстрируется сама идея обработки данных.
Примерно так:
[code h=200]
.386
.model flat, stdcall
option casemap :none

;подключаем необходимые inc-файлы
include \masm32\include\windows.inc
;include \masm32\include\user32.inc
include \masm32\include\kernel32.inc

;и библиотеки
;includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib

;прототипы функций
StdOut PROTO :DWORD, :DWORD
GetNibble PROTO
GetNum PROTO
CalcText PROTO :DWORD, :DWORD, :DWORD

;стек
.stack 1024

;сегмент данных
.data
sMD5 db "F4D531675F637A9745967E883A7AB18E"
lenMD5 equ ($-sMD5)/2 ;количество данных
sData db "0123456789ABCDEFGHJKLMNPQRTUVWXY"
sTitle db "Decoding text: "

.data?
sText db 256 dup (?)

;сегмент кода
.code
main proc
local hOutPut:DWORD ;описатель стандартного выходного устройства
;получаем handle устройства
invoke GetStdHandle, STD_OUTPUT_HANDLE
mov hOutPut, eax

;выводим "Decoding text: "
invoke StdOut, hOutPut, addr sTitle

invoke CalcText, addr sMD5, lenMD5, addr sText

;выведем строку
invoke StdOut, hOutPut, addr sText
;выход
invoke ExitProcess, NULL
main endp

GetNibble proc ;hex-символ в hex-число 0-f
lodsb
sub al, '0'
cmp al, 9 ;0-9 ?
jbe GetNibbleRet
sub al, 'A'-'0'-0ah ;A-F
GetNibbleRet:
ret
GetNibble endp

GetNum proc ;два hex-символа в байт
call GetNibble
shl al, 4
mov ah, al
call GetNibble
or al, ah
ret
GetNum endp

CalcText proc uses esi ecx edi, pMD5:DWORD, iCount:DWORD, pText:DWORD
mov esi, pMD5 ;адрес массива
mov ecx, iCount ;его длина
mov edi, pText
CalcTextLoop:
call GetNum
and eax, 0000001fh
mov al, sData[eax]
stosb
loop CalcTextLoop
mov byte ptr [edi], 0 ;закроем строку нулем для вывода
ret
CalcText endp

;вывод строки на стандартное выходное устройство
;параметр - адрес строки
StdOut proc hOutPut:DWORD, lpszText:DWORD
;локальные переменные в стеке
LOCAL bWritten:DWORD ;количество выведенных символов
LOCAL len:DWORD ;длина строки

;получаем длину строки
invoke lstrlen, lpszText
mov len, eax

;выводим
invoke WriteFile, hOutPut, lpszText, len, ADDR bWritten, NULL

;возвращаем количество выведенных символов
mov eax, bWritten
ret
StdOut endp

end main
[/code]