Здравствуйте, Березин Вадим Юрьевич!
Первый вариант, с функцией ЕСЛИ
=ЕСЛИ(B1<=4;100;ЕСЛИ(B1<=8;150;ЕСЛИ(B1<=12;200;300)))
Второй вариант, на булевых функциях
=100+50*(B1>4)+50*(B1>8)+100*(B1>12)
У меня нет Office 2010, но в списках новинок ничего про эти функции не написано, предполагаю, что они не изменились.

Здравствуйте, Березин Вадим Юрьевич!

=ЕСЛИ(B1<>"";ЕСЛИ(B1<4;100;ЕСЛИ(B1<8;150;ЕСЛИ(B1<12;200;ЕСЛИ(B1>=12;300;""))));"")

Здравствуйте, Березин Вадим Юрьевич!
Вот формула для получения результата:
=ЕСЛИ(B3<=4;F1;0)+ЕСЛИ(И(4<B3;B3<=8);G1;0)+ЕСЛИ(И(8<B3;B3<=12);H1;0)+ЕСЛИ(12<B3;I1;0)
Заменяем В3 на нужное значение (В4, В5...) и получаем нужный результат.

Лучше так:
=ЕСЛИ(B3<=4;$F$1;0)+ЕСЛИ(И(4<B3;B3<=8);$G$1;0)+ЕСЛИ(И(8<B3;B3<=12);$H$1;0)+ЕСЛИ(12<B3;$I$1;0)
Тогда можно будет формулу распространить на нижние ячейки протягиванием, без замены В3 на нужное значение вручную - адреса изменятся сами, адреса же ячеек, где записаны выходные значения (100, 150, 200, 300) не изменятся.
Если адреса этих ячеек не сделать абсолютными, при протягивании результат будет неверным.

Здравствуйте, Березин Вадим Юрьевич!
Вот еще решение. Здесь я применил очень большие по абсолютной величине числа: отрицательное -1E307 и положительное 1E307. Реально в Вашей задаче они не будут достигнуты, мне они нужны, чтобы определить интервалы чисел.

Пронумеруем интервалы:

1) 12<b<=1E307
2) 8<b<=12
3) 4<b<=8
4) -1E307<b<=4

Значения
1) 300
2) 200
3) 150
4) 100

Тогда, чтобы найти, в каком по номеру интервала находится вводимое число, используем функцию ПОИСКПОЗ.
Выбор значения из массива значений 300;200;150;100 для каждого интервала для найденного значения номера интервала осуществит функция ВЫБОР
Итак, формула: Чем привлекательно решение -
1. Оно более наглядно
2. Интервалов может быть 29, с помощью ЕСЛИ такого не напишешь

Здравствуйте, Березин Вадим Юрьевич!

Для всех вычислений используется формула "Если":

ЕСЛИ(лог_выражение1; значение_если_истина1; значение_если_ложь1)

лог_выражение1 - Ваше первое условие - Dn <= 4
значение_если_истина1 - Мы знаем, подставляем - 100

Итак, получится первая часть задачи:

ЕСЛИ(Dn <= 4;100;значение_если_ложь1)

А что будет, в третьем параметре значение_если_ложь1?

-------------------------------------------------------------------------------------

В третьем параметре будет следующая формула "ЕСЛИ", а именно:

Значение_если_ложь1 =

ЕСЛИ(лог_выражение2;значение_если_истина2;значение_если_ложь2)

лог_выражение2 - Ваше четвёртое условие - Dn > 12
значение_если_истина2 - Мы знаем, подставляем - 300

ЕСЛИ(Dn > 12;300;значение_если_ложь2)

-------------------------------------------------------------------------------------

В третьем параметре будет следующая формула "ЕСЛИ", а именно:

Значение_если_ложь2 =

ЕСЛИ(лог_выражение3;значение_если_истина3;значение_если_ложь3)

лог_выражение3 - Ваше третье условие - Dn > 8
значение_если_истина3 - Мы знаем, подставляем - 200

ЕСЛИ(Dn > 8;200;значение_если_ложь3)

-------------------------------------------------------------------------------------

В третьем параметре остается только значение 150.

значение_если_ложь3 = 150

ШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШШ

Собираем всё в одну формулу:

ЕСЛИ(Dn <= 4;100;

___ЕСЛИ(Dn > 12;300;

-----___ЕСЛИ(Dn > 8;200;
-----___------150
-----___)
___)
)

Итог:
=ЕСЛИ(D1 <= 4;100;ЕСЛИ(D1 > 12;300;ЕСЛИ(D1 > 8;200;150)))