Главная Вход в систему Регистрация
Задать вопрос Консультации Пользователи Форум
О системе Помощь
Задать вопрос экспертам
Консультация № 160846
18.02.2009, 20:46
0.00 руб.
0 5 1
Компьютеры Программирование
Подскажите, как из Делфи создать документ Ворд, установить параметры страницы и ввести туда любой текст? Достаточно удачных ссылок

Обсуждение

давно
Евгений/Genia007/
Профессионал
153662
1070
18.02.2009, 21:18
общий
это ответ
Здравствуйте, Oleg Adamenko!

Вот статья с сайта delphi world. вот ссылка на этот сайт URL >> там есть ещё статьи.
Для создания документа Microsoft Word из Delphi нужно создать переменную, ассоциированную с Word. Если Word еще не открыт, его нужно открыть.
Код:
uses ComObj;

procedure TForm1.Button1Click(Sender: TObject);
var
  MSWord: Variant;
begin
  try
    MsWord := GetActiveOleObject('Word.Application');
  except
    try
      MsWord := CreateOleObject('Word.Application');
      MsWord.Visible := True;
    except
      Exception.Create('Error');
    end;
  end;
  MSWord.Documents.Add;
  MSWord.Selection.Font.Size := 12;
  MSWord.Selection.TypeText('Текст');
  MSWord.Selection.Font.Bold := true;
  MSWord.Selection.TypeText(#13#10'new');
  MSWord.ActiveDocument.SaveAs('C:\ex.doc');
end;


Работа с текстом

Сначала о самом простом - добавлении в документ Word нужной строки текста. Поместим на форму компоненты WordDocument, WordApplicationи WordParagraphFormat с палитры Servers. Нас интересуют в первую очередь свойство Range компонента WordDocument и свойство Selection компонента WordApplication. Классики утверждают, что они являются ссылкой на объекты Range и Selection. Range представляет из себя, проще говоря, кусок текста, это может быть как весь текст документа, так и любая его часть. Его пределы задаются двумя (или меньше) параметрами типа OleVariant.

Например:
Код:
var  range1, range2, range3, a, b : OleVariant;
     ...
     range1:=WordDocument1.Range;
     a:=5;
     b:=15;
     range2:=WordDocument1.Range(a,b);
     range3:=WordDocument1.Range(a);

Первый наш объект включает в себя весь текст документа, у второго мы ограничили пределы 5-м и 15-м символами, третий представляет из себя весь последующий текст документа, начиная с 5-го символа. Объект имеет несколько полезных методов, например, с его помощью можем добавить текст в документ:
Код:
range2.InsertAfter('MS Word');


Это мы вставили текст после выделенного Range. Точно также можем вставить текст и перед ним, для этого служит метод InsertBefore(). Текст, заключенный в объекте Range, можем получить так:
Код:
WordDocument1.Range(a,b).Text;


Кроме того, с помощью Range можем изменить шрифт в пределах объекта. Пример:
Код:
a:=5;
b:=15;
WordDocument1.Range(a,b).Font.Bold:=1;
WordDocument1.Range(a,b).Font.Size:=14;
WordDocument1.Range(a,b).Font.Color:=clRed;


Если хотим отменить выделение жирным шрифтом, присваиваем 0. Аналогично можно сделать шрифт курсивом, подчеркнутым - наберите WordDocument1.Range.Font., и среда сама подскажет, какие могут быть варианты. Методы Select, Cut, Copy и Paste работают как в обычном тексте. С помощью Paste можем на место выбранного Range вставить не только строки, но и рисунок, находящийся в буфере обмена.
Код:
WordDocument1.Range(a,b).Select;
WordDocument1.Range(a,b).Cut;
WordDocument1.Range(a,b).Copy;
WordDocument1.Range(a,b).Paste;


С помощью Range можем найти в документе нужную строку. Пусть в тексте содержится слово " picture" . Например, нам на его место надо будет вставить рисунок.
Код:
var a, b, vstart, vend: OleVariant;
j, ilengy: Integer;
...
ilengy:=Length(WordDocument1.Range.Text);
for j:=0 to ilengy-8 do begin
a:=j;
b:=j+7;
if WordDocument1.Range(a,b).Text='picture' then begin
vstart:=j;
vend:=j+7;
end;
end;
WordDocument1.Range(vstart,vend).Select;


Такая процедура находит и выделяет нужный кусок текста.

Теперь про Selection, представляющий из себя выделенный фрагмент документа. Если выделения нет, это текущая позиция курсора в документе. С его помощью можем вставить что-либо на место выделенного фрагмента, сделать выравнивание, изменить шрифт. Он также имеет методы InsertAfter() и InsertBefore():

Код:
WordApplication1.Selection.InsertAfter(" text1" );
WordApplication1.Selection.InsertBefore(" text2" );


Форматирование выделенного текста происходит аналогично Range, например:
Код:
WordApplication1.Selection.Font.Bold:=1;
WordApplication1.Selection.Font.Size:=16;
WordApplication1.Selection.Font.Color:=clGreen;


Для выравнивания проще воспользоваться компонентом WordParagraphFormat. Сначала только нужно " подключить" его к выделенному фрагменту текста:
Код:
WordParagraphFormat1.ConnectTo(WordApplication1.Selection.ParagraphFormat);
WordParagraphFormat1.Alignment:=wdAlignParagraphCenter;


Значения его свойства Alignment может принимать значения wdAlignParagraphCenter, wdAlignParagraphLeft, wdAlignParagraphRight, смысл которых очевиден. Имеются и методы Cut, Copy и Paste, которые в пояснениях вряд ли нуждаются:
Код:
WordApplication1.Selection.Cut;
WordApplication1.Selection.Copy;
WordApplication1.Selection.Paste;

Убираем выделение с помощью метода Collapse. При этом необходимо указать, в какую сторону сместится курсор, будет ли он до ранее выделенного фрагмента или после:
Код:
var vcol: OleVariant;
...
vcol:=wdCollapseStart;
WordApplication1.Selection.Collapse(vcol);


При этом выделение пропадет, а курсор займет позицию перед фрагментом текста. Если присвоить переменной значение wdCollapseEnd, то курсор переместится назад. Можно просто поставить в скобках " пустышку" :
Код:
WordApplication1.Selection.Collapse(EmptyParam);

Тогда свертывание выделения производится по умолчанию, к началу выделенного текста.
Об авторе:
Мои программы со статусом freeware для Windows на моём сайте jonix.ucoz.ru
давно
Вадим Исаев ака sir Henry
Мастер-Эксперт
425
4118
19.02.2009, 06:17
общий
Только учтите, что сам Word должен стоять на компьютере.
Об авторе:
Я только в одном глубоко убеждён - не надо иметь убеждений! :)
Неизвестный
19.02.2009, 13:06
общий
Если хотите более подробно изучить этот вопрос, а также освоить взаимодействие не только с MS Word, но и с другими приложениями MSOffice, рекомендую почитать книгу Василия Корнякова "Программирование документов и приложений MS Office в Delphi". Удачи в освоении!
Неизвестный
20.02.2009, 19:50
общий
За помощь спасибо. Осталось два вопроса: как создать документ ворд из делфи, как вставлять колонтитулы (в частности, номера строк) и главное: как соединить несколько докумнентов ворд, не открывая их, в определенной заданной последовательности?
давно
Евгений/Genia007/
Профессионал
153662
1070
20.02.2009, 21:59
общий
Вот ещё статья на эту тему:

Здесь мы рассмотрим пример того, как управлять объектами Word-а (Excel - аналогично) из программ на Delphi. Исходный код примера можно скачать на страничке 'DownLoad'

Для чего это нужно

Задачи могут быть самые разные, в общем случае это использование возможностей Word-а в своей программе, н-р: проверка текста на орфографию; печать текста, графики; экспорт отчетов в Word или изначальное создание их там и т.д.

Подготовительные работы

На самом деле существует несколько способов сделать это, мы рассмотрим только один (пример кроме Delphi 5, в Delphi5 для этого есть компоненты на закладке Servers переименуете в программе типы на соответствующие компоненты, дальше так же). Для начала начнем новый проект File, New Application; File, Save All. Создадим отдельную папку для проекта и сохраним Unit1 как Main, а Project1 как WordWriter. Далее для работы с Word-ом нам потребуется библиотека типов Word-а, это делается так: Project, Import Type Library, Add, далее переходим в папку, где стоит Word ( у меня это - "c:\program files\microsoft office) , заходим в папку Office и выбираем файл - msword8.olb (цифра -? версии Word-а - у Вас может отличаться ) или excel8.olb (для Excel).Нажимаем Оk. Delphi создаст 2 файла - Word_tlb.pas и Office_tlb.pas, их надо включить в раздел uses модуля Main нашего проекта:

uses
Office_Tlb, word_tlb;


Теперь займемся непосредственно программированием

В разделе var опишем следующие переменные:
Код:
// класс приложения ворда
WordApp: Word_tlb.Application_;
// класс чего-то типа выделения,
// т.е. говоришь - выделить ячейку с ... по, а результат скидываешь
// в эту перем и работаешь с этими ячейками как с 1 объектом
ARange, TempRange: Range;
// массив документов
Docs: documents;
// 1 документ
Doc: document;
// массив параграфов
pars: Paragraphs;
// 1 параграф
par: Paragraph;
// параметры для передачи
Template, temp, OpenAsTemplate: olevariant;
// массив таблиц
tabls: Tables;
// 1 таблица
tabl: Table;
// рабочая переменная
i: integer;



Далее проектируем форму:

Поместим вверх нашей формы кнопку - button1 типа tbutton, поменяем заголовок (св-во Caption) на 'Старт'.
Под кнопкой разместим панель - panel1 типа tpanel. Внутри панели поместим компонент - bevel1 типа tbevel, поменяем св-во Align на alClient (при этом рамка растянется на всю панель).
Сверху панели (далее все компоненты будут размещаться внутри этой панели) разместим метку - label1 типа tlabel, поменяем значение св-ва Caption на 'Передать в ячейку':
Ниже слева поместим метку - label1 типа tlabel, св-во Caption поменяем на 'X='
Правее метки помещаем компонент Edit1 типа tEdit, св-во Text меняем на '1'
По правой границе Edit1 помещаем компонент UpDown1 типа tUpDown, в списке св-ва 'Associate' выбираем Edit1, св-во 'Position' приравниваем '1'
Чуть отступаем вправо и повторяем шаги 4-6 , заменив Edit1 на Edit2, UpDown1 на UpDown2, Label1 на Label2 соответственно.
Ниже размещаем еще одну метку - label4 типа tlabel, меняем св-во 'Caption' на 'Новое значение ячейки:'
Ниже размещаем компонент Edit3 типа tEdit, св-во Text меняем на '0'
И, наконец, в самом низу панели размещаем кнопку BitBtn1 типа tBitBtn, меняем св-во 'Kind' на 'bkOk'.
Теперь напашем обработчики - именно в них и заключается вся функциональность программы:

Назначим обработчик OnClick компоненту Button1.

Код:
procedure TForm1.Button1Click(Sender: TObject);
begin
  // если заголовок 'Выход', то закрываем программу
  if button1.caption='Выход' then
  begin
    Application.Terminate;
    exit;
  end
  // иначе (при первом начатии, когда у нас заголовок 'Старт')
  //переименовываем заголовок в 'Выход'
  else
    button1.caption:='Выход';

  panel1.Visible:=true;
  // создаем экземпляр ворда
  WordApp:=CoApplication_.Create;
  // делаем его видимым
  WordApp.Visible:=true;
  // шаблон
  template:='Normal';
  // создать шаблон
  OpenAsTemplate:=false;
  // что-то типа оператора with, можно было и напрямую обратиться
  Docs:=WordApp.Documents;
  // добавляем документ
  Doc:=Docs.Add(template,OpenAsTemplate);

  // выделить все
  ARange:=Doc.Range(EmptyParam,EmptyParam);
  // массив параграфов
  pars:=doc.Paragraphs;
  // переменная - параметр
  template:=arange;
  // новый параграф
  par:=pars.Add(template);
  // цвет зеленный
  par.Range.Font.ColorIndex:=11;
  // вставляем текст
  par.Range.InsertBefore('Привет !!!');
  // переменная - параметр
  template:=par.Range;
  // новый параграф, чтобы таблица не потерла текст
  par:=pars.Add(template);
  // цвет черный
  par.Range.Font.ColorIndex:=0;
  // вставляем текст
  par.Range.InsertBefore('Переключившись в программу, ' +
  'можно программно менять текст ячеек !');
  // переменная - параметр
  template:=par.Range;
  // новый параграф, чтобы таблица не потерла текст
  par:=pars.Add(template);
  // выделяем параграф
  arange:=par.Range;

  // шрифт - жирный
  ARange.Font.Bold:=1;
  // шрифт - рукописный
  ARange.Font.Italic:=1;
  // получить массив таблиц
  tabls:=aRange.Tables;
  // добавляем новую таблицу размером 5 на 5
  tabl:=tabls.Add(arange,5,5);
  // в цикле
  for i := 1 to 5 do
    // задаем значение ячеек
    tabl.Cell(i,1).Range.Text := inttostr(i);
end;



Зададим обработчик формы:

Код:
procedure TForm1.FormDestroy(Sender: TObject);
var
  // для параметров
  SaveChanges: olevariant;
begin
  // если Word не закрыт
  if not VarIsEmpty(WordApp) then
  begin
    { а можно сохранить автоматом:
    // имя файла в оле
    template:='Имя.doc';
    // если не сохранен, то
    if doc.Saved=false then
    // сохраняем
    Doc.SaveAs(template, EmptyParam, EmptyParam, EmptyParam, EmptyParam,
    EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam, EmptyParam);

    короче, пишешь имя объекта, ставишь точку и нажимаешь
    'ctrl'+' ' и изучаешь существующие методы и св-ва
    }
    //изменения не сохранять
    SaveChanges:=false;
    // то закрыть сначала документ
    Doc.Close(SaveChanges,EmptyParam,EmptyParam);
    // а потом и ворд
    WordApp.Quit(SaveChanges,EmptyParam,EmptyParam)
  end;
end;



Назначим обработчик OnClick компоненту Bitbtn1:

Код:
procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  // в соотв ячейку ставим соотв значение,
  // а можно и наоборот - получать значение из ячейки в переменную
  tabl.Cell(UpDown2.Position,UpDown1.Position).Range.Text:=Edit3.Text;
end;



В общем-то, это все ...

Дополнительная информация:

Справка Word-а (по Visual Basic, по умолчанию она не ставится - запустите заново Setup и поставте в соотв. месте галочку)
Книги:
Чарльз Калверт "Энциклопедия пользователя Delphi4" (издательство - DiaSoft)
Марко Кэнту "Delphi4 для профессионалов" (издательство - Питер)
Если у Вас другая версия Word-а:

Параметры ф-ций могут отличаться - обратитесь к справке (см выше) или если у Вас версия Delphi 3 и выше, то используем универсальный метод - пишешь имя объекта, ставишь точку (если нужно посмотреть список параметров у функции , то после открывающей скобки ) , нажимаешь 'ctrl'+'пробел' и изучаешь существующие методы и св-ва.
Об авторе:
Мои программы со статусом freeware для Windows на моём сайте jonix.ucoz.ru
Форма ответа