Здравствуйте, angel.nero.
В приложении код программы. Для определения числа решений использую правило Крамера (ссылка в комментарии в коде программы).
Пример окна программы:

Жалобы на сложность принимать не буду: лучше спрашивайте - объясню, что к чему

Прикрепил файл с исходным кодом программы

Приложение:
TYPE
solutions = (sSingle, sMultiple, sNone);

{Функция для получения вещественного числа - с проверкой правильности}
function GetReal(msg: String): Real;
var
r: Real;
code: Integer;
begin
repeat
Write(msg,' ');
{$I-} ReadLn(r); {$I+}
code := IOResult;
if code <> 0 then WriteLn('Ошибка ввода');
until code = 0;
GetReal := r
end;

{Функция для проверки решения}
function TestSolution(a, b, c, d, e, f, x, y: Real): Boolean;
begin
TestSolution := (a*x + b*y = c) and (d*x + e*y = f);
end;

{Функция для определения числа решений
Находим по правилу Крамера
http://www.bymath.net/studyguide/alg/sec/alg15.html}
function SolutionCount(a, b, c, d, e, f: Real): solutions;
var DET: Real;
begin
DET := (a*e - b*d);
if DET <> 0 then SolutionCount := sSingle
else
begin
SolutionCount := sMultiple;
{Но именно здесь может получиться, что нет решений.
Проблема усложняется тем, что какие-то коэффициенты могту быть равны 0}
if (a*f <> c*d) or (b*f <> c*e) then
{так записываю отношения, чтобы избежать деления на ноль}
SolutionCount := sNone
end;
end;

VAR
a, b, c, d, e, f: Real;
x, y: Real;
BEGIN
WriteLn('Решение системы уравнений');
WriteLn(' ax + by = c');
WriteLn(' dx + ey = f');

a := GetReal('Введите значение коэффициента a:');
b := GetReal('Введите значение коэффициента b:');
c := GetReal('Введите значение коэффициента c:');

d := GetReal('Введите значение коэффициента d:');
e := GetReal('Введите значение коэффициента e:');
f := GetReal('Введите значение коэффициента f:');

WriteLn('Решается система уравнений:');
WriteLn(' ',a:10:6,'x + ',b:10:6,'y = ',c:10:6);
WriteLn(' ',d:10:6,'x + ',e:10:6,'y = ',f:10:6);

WriteLn;
WriteLn('Введите Ваш вариант решения');
x := GetReal(' Значение x: ');
y := GetReal(' Значение y: ');

WriteLn('Значения x = ',x:10:6,' и y = ',y:10:6);
if NOT TestSolution(a, b, c, d, e, f, x, y) then
Write(' не');
WriteLn(' являются решениями системы уравнений');

WriteLn('Количество решений: ');
Case SolutionCount(a, b, c, d, e, f) of
sSingle : WriteLn(' единственное');
sMultiple: WriteLn(' множество решений');
sNone : WriteLn(' нет решения');
end;
END.