Здравствуйте, Артем Борисовский.

В приложении - исправленная программа. Замечания помечены ;!
Ваша программа рассчитана не только на 2-значные, но и на 16-ричные числа до 4-х значащих цифр. Буквы должны быть в верхнем регистре.
Преобразование в 10-тичную и 2-ичную системы правильное, но слишком маленькие буфера для результатов. Кроме того, перед преобразованием в 2-ичную систему число уже было утеряно.
Чуток поправил сообщения.

Работу программы проверил.

Успехов!

Приложение:
cod segment
assume cs:cod,ds:cod
org 100h
begin:
mov dx,offset Start
call Message
;Чтение из командной строки
xor cx,cx
; mov bx,80h
; mov cl,[bx] ;! в принципе, это правильно, но излишне
mov cl,byte ptr DS:[80h] ;! проще (и на байт короче) так
;! DS: добавляем, чтобы TASM распознал 80h как адрес
; получение длины
test cx,cx
jnz CommLineSet
mov dx,offset NoCmd
call Message
jmp Exit

CommLineSet:
; вставлем число в регистр dx
dec cx
cld
; lea si,[bx+2] ;! для Вашего кода это было правильно
mov si,82h ;! так проще
xor dx,dx

PutNumbToAX:
; вставлем число в регистр ax
shl dx,4
lodsb
sub al,'0'
cmp al,9
jbe TransDone
sub al,('A'-'0')-10
TransDone:
or dl,al
loop PutNumbToAX

;Конвертируем в десятичную и выводим на экран
push dx ;! сохраняем для последующего перевода в двоичную систему
push dx
mov dx,offset ResPrompt
call Message
pop ax
mov cx,5
mov bx,10000
mov di,offset Symbols

GetDigit: ;процедура перевода в десятичную СС
xor dx,dx
div bx
add al,'0'
stosb
push dx
mov ax,bx
xor dx,dx
mov bx,10
div bx
mov bx,ax
pop ax
loop GetDigit
mov dx,offset Symbols
call Message

; Конвертируем в двоичную и выводим на экран
;! push dx - нужно было поместить в стек раньше, здесь DX = offset Symbols
mov dx,offset ResPromptBin
call Message
pop dx
mov cx,16
mov di,offset SymbolsBin
GetBin: ; процедура перевода в двоичную СС
xor ax,ax
shl dx,1
adc al,'0'
stosb
loop GetBin
mov dx,offset SymbolsBin
call Message
Exit: ; Выход
mov dx,offset Finish
call Message
xor ah,ah ; ждем нажатия любой клавиши (чтобы увидеть результат,
int 16h ; прежде чем консоль в Windows закроется)
retn

Message: ;процедура вывода на экран
mov ah,09h
int 21h
retn


Start db 'Start !',0ah,0dh,'$'
NoCmd db 'No specified symbols in CMD !',0ah,0dh,'$'
ResPrompt db 'Result in decimal: $'
ResPromptBin db 'Result in bin: $'
Symbols db 5 dup ('0'),0ah,0dh,'$' ;! 5 символов для десятичного числа
SymbolsBin db 16 dup('0'), 'b',0ah,0dh,'$' ;! 16 символов для двоичного числа
Finish db 'Finish! Press any key to exit...',0ah,0dh,'$'
cod ends
end begin

Здравствуйте, Артем Борисовский.
Моя версия подправленной программы.
Вводит 1 байт, не более 2 hex-цифр из командной строки.
Добавил проверку на ошибки: проверяются символы на корректность, число цифр
Поменял вывод десятичного числа.