Здравствуйте, Ивлев Дмитрий!
Если только выделить, то можно воспользоваться условным форматированием.
Например, ваши числа находятся в диапазоне A2:A26, выделяете этот диапазо (текущей ячейкой при этом должна быть ячейка A2), далее Формат-Условное форматирование, выбираете "формула" и вводите формулу =ОСТАТ($A2;2)<>0
на кнопке "Формат..." задаете каким цветом выделить ваше "каждое второе значение"
и нажимаете Ок (после задания формата) и Ок (чтобы задать условие и выйти из условного форматирования)

и все :)

Здравствуйте, Ивлев Дмитрий!
В ответе решил разместить более гибкий и универсальный вариант решения вашей задачи.
Размещаете, где вам нужно НА ОДНОМ ЛИСТЕ С ИСХОДНЫМИ ДАННЫМИ формулу
=ДВССЫЛ(АДРЕС(СТРОКА($A$2)-1+2*(СТРОКА()-СТРОКА($A$2)+1);СТОЛБЕЦ($A$2);4))
и копируете ее в нужное количество ячеек.
В данной формуле $A$2 - абсолютная ссылка на первую ячейку столбца с данными.
Множитель "2" можно изменять, т.е. заменив его на 3 :
=ДВССЫЛ(АДРЕС(СТРОКА($A$2)-1+3*(СТРОКА()-СТРОКА($A$2)+1);СТОЛБЕЦ($A$2);4))
получите в результирующем столбце каждый третий элемент.
Если потребуется, можно заменить эту константу в формуле на ссылку(абсолютную), например,
=ДВССЫЛ(АДРЕС(СТРОКА($A$2)-1+$B$1*(СТРОКА()-СТРОКА($A$2)+1);СТОЛБЕЦ($A$2);4))
позволит вам меняя значение ячейки B1 получать каждый B1-й элемент столбца с данными.
И последнее. Все описанное выше, решает вашу задачу в формулировке, приведенной в конце вопроса, т.е "каждое второе (ну, или B1-е) значение".
В примере же, который вы приводите, выводится 1-е значение и потом каждое "второе+1" значение.
Добиться этого можно так:
=ДВССЫЛ(АДРЕС(СТРОКА($A$2)+$B$1*(СТРОКА()-СТРОКА($A$2));СТОЛБЕЦ($A$2);4))
Все.
Рад был помочь!

Здравствуйте, Ивлев Дмитрий!
Предлагаю еще вариант решения, с несколько более короткой формулой:
Пусть в клетках $C8:$C23 содержатся Ваши данные
Для выборки только нечетных элементов в соседней клетке, например, D8, можно написать формулу

=ИНДЕКС($C8:$C23;СТРОКА($C8)-СТРОКА($C$8)+1;1)
Для получения значений в других ячейках формулу размножаем стандартным образом на ячейки вниз.

При этом определение формулы вне строк исходных данных вызовет сообщение #ССЫЛКА!
При вставке строк внутри диапазона формула корректным образом трансформируется.

Для произвольного случая возможен вариант формулы
Пусть в диапазоне $C$8:$C$23 содержатся Ваши данные, тогда тогда формула для выборки в нечётных строках (то есть через 2 начиная с первой) будет иметь вид
=ИНДЕКС($C$8:$C$23;(СТРОКА($C8)-СТРОКА($C$8))*2+1;1)

Через 3 начиная с первой соответственно формула примет вид
=ИНДЕКС($C$8:$C$23;(СТРОКА($C8)-СТРОКА($C$8))*3+1;1)

и т д.

Для получения значений в других ячейках формулу размножаем стандартным образом на ячейки вниз.

При этом при выходе выбираемых данных за пределы исходных данных (вне определённого Вами диапазона) функция выдаст ошибку #ССЫЛКА!
Вставка строк внутрь диапазона здесь, увы, не приведёт к корректной трансформации формул, формулы заново надо будет повторить для всех ячеек.

Все приведенные формулы корректно трансформируются при вставке столбцов и строк вне диапазона расположения исходных данных