Здравствуйте, ann.zinger2010!

Смотрите код:
[code lang=asm h=300]model small
.data
szStr equ 250
dbStrng db 10,13,'Enter string:$'
dbPstn db 10,13,'Enter position:$'
dbLngth db 10,13,'Enter length:$'
dbCnt db 10,13,'Enter count:$'
dbRes db 10,13,'Result:$'

dbMax db szStr
dbLen db ?
dbStr db 2*szStr dup(?)

dwNum1 dw ?;
dwNum2 dw ?;
dwNum3 dw ?;
.stack 100h
.code
;адресуем сегментные регистры
begin: mov ax,@data
mov ds,ax
mov es,ax
;просим ввести строку
Str1: mov ah,9
lea dx,dbStrng
int 21h
;вводим
mov ah,10
lea dx,dbMax
int 21h
;контроль пустой строки
mov al,dbLen
or al,al
jz Str1
;просим ввести позицию
Num1: lea dx,dbPstn
call InpNum
dec ax
;контролируем позицию и длину строки
cmp al,dbLen
jae Num1;больше повторяем
mov dwNum1,ax
;просим ввести длину копируемого участка
Num2: lea dx,dbLngth
call InpNUm
;контролируем длину копирования и длину строки
mov bl,dbLen
add bl,al
cmp bl,dbLen
jb Num2;больше переходим
mov dwNum2,ax
;просим ввести количество копий
Num3: lea dx,dbCnt
call InpNUm
mov dwNum3,ax
;готовим строку для вывода
lea si,dbStr
mov dl,dbLen
xor dh,dh
add si,dx
mov byte ptr[si],'$'
;готовимся к перерносу кода
mov bx,dwNum2
mul bl
mov di,ax;=количество копий * длина копирования
add di,si
dec di
xor ch,ch
mov cl,dbLen
add si,dwNum1
sub cx,dwNum1
;перносим
std
rep movsb
;готовимся копировать код
mov cx,dwNum3
lea si,dbStr
mov ax,dwNum2
add si,dwNum1
mov di,si
cld
;копируем
Copy1: push si
push cx
mov cx,ax
rep movsb
pop cx
pop si
loop Copy1
;выодим результат
mov ah,9
lea dx,dbRes
int 21h
mov ah,9
lea dx,dbStr
int 21h
;выход
mov ax,4C00h
int 21h
;вводим одну цифру
InpNum: mov ah,9
int 21h
mov ah,1
int 21h
;не цифра повторяем ввод
cmp al,'1'
jb InpNum
cmp al,'9'
ja InpNum
and ax,0Fh
ret
end begin[/code]
Удачи!