Здравствуйте, Посетитель - 399158!
Строки с большими и малыми буквами лишние.
Они отличаются значением 20h.
Этим и воспользуемся...
[code h=200]data segment
message db 'Vvedite proizvolnyi text ili nabor simvolov,lish v latinic:',0dh,0ah,'$'
stroka db 80,0,80 dup(?) ;для функции 0ah требуется указать в первом байте
;длину буфера, во втором будет реальная длина
data ends

code segment
assume cs:code,ds:data

begin:
mov ax,data
mov ds,ax
lea dx,message
mov ah,09h
int 21h
lea dx,stroka
mov ah,0ah
int 21h ;ввели строку

mov dl,0ah
mov ah,2
int 21h ;перейдем на новую строку

lea si,stroka+2 ;все правильно - имеем адрес самой строки
mov dx,si ;сохраним для вывода, все замены сделаем на месте
xor cx,cx ;счетчик байт
mov cl,stroka+1 ;реальное количество введенных байт
mov ah,20h ;большие и малые буквы отличаются этим битом!
;будем превращать их друг в друга xor-я с этим байтом!
beg:
mov al,[si] ;читаем очередной байт
xor al,ah ;превращаем одного в другого (и неважно, какой он был!)
mov [si],al ;возвращаем на место
inc si ;адрес следующего
loop beg ;цикл по всем

mov byte ptr [si],'$' ;закрываем строку для функции 9
mov ah,9
int 21h ;выводим

mov ah,0
int 16h ;ждем нажатие на клавишу

mov ax,4c00h
int 21h
code ends
end begin
[/code]