;Построение графика функции f(x)=cos(n*x+m*Pi), 
;входные данные -- n и m, выходные -- график. 

	.model	tiny, C		; модель памяти и порядок вызова параметров
	.386			; нужно для команды fcos
	.code			; сегмент кода
	.startup		; точка входа

;введем N и M 
	call	GetNum, offset sN, offset NMax, offset N
	call	GetNum, offset sM, offset MMax, offset M

;преходим в графику
	mov	ax, 0013h	; vga 320x200x256
	int	10h

	mov	ax, 0a000h
	mov	es, ax		; es - сегмент видео

	call	line, 20, 100, 300, 100, 8	;ось абсцисс	
	call	line, 160, 20, 160, 180, 8	;ось ординат
	call	Graph, 20, 300, offset fun, 0bh	;сам график
	call	PrFun, 3			;напишем функцию

	mov	ah, 0		;ждем нажатие на любую клавишу
	int	16h

;выход в DOS
	mov	ax, 0003h	; назад в текстовый режим
	int	10h

	mov	ax, 4c00h	; bye-bye
	int	21h

;Вводим вещственное число
;параметры:
;pStr - адрес строки приглашения
;pMax - адрес строки для ввода по функции 0ah
;pNum - адрес, куда пишем вещественное число
GetNum	proc	pStr:word, pMax:word, pNum:word
local	i:word			;переменная для работы с сопроцессором

	mov	dx, pStr	;приглашение
	mov	ah, 9
	int	21h

	mov	dx, pMax	;вводим строку
	mov	si, dx
	mov	ah, 0ah
	int	21h

	lea	si, [si+2]	;на адрес введенной строки
	xor	cx, cx		;ch=0 - признак целой части, ch=1 - дробная часть
	xor	di, di		;число (без учета точки)
GN_loop:
	lodsb			;очередной символ
	cmp	al, 0dh
	je	GN_Form		;прошли по всей строке
	cmp	al, '.'
	je	GN_Point	;точка
	cmp	al, '0'
	jb	GN_loop		;допускаем только цифры
	cmp	al, '9'
	ja	GN_loop

	cmp	ch, 0
	je	GN_dig		;целая часть - на формирование числа
	inc	cl		;дробная - сначала посчитаем число цифр дробной части
GN_dig:
	push	ax		;умножаем старшие разряды на 10 и добавляем новый
	mov	ax, 10
	mul	di
	mov	di, ax
	pop	ax
	and	ax, 0fh
	add	di, ax
	jmp	GN_loop
GN_Point:			;точка
	cmp	ch, 1
	je	GN_loop		;если повтор точки, то игнорируем (на всякий случай)
	mov	ch, 1		;помечаем
	jmp	GN_loop
GN_Form:			;учтем дробную часть
	mov	i, di		;запишем число в переменную
	fild	i		;загрузим в сопроцессор
	mov	ch, 0		;сформируем счетчик во всем регистре cx
	jcxz	GN_Save		;если дробной части нет, то на сохранение
	mov	i, 10		;константа для деления
GN_Div:
	fild	i		;cx раз делим на 10
	fdiv
	loop	GN_Div
GN_Save:
	mov	di, pNum	;адрес, куда сохраняем вещественное число
	fstp	dword ptr [di]	;сохраняем результат в виде float
	ret
GetNum	endp

;считает ax=y=f(x) в экранных координатах 
;параметр: x - экранная координата по горизонтали
fun	proc	x:word
	mov	ax, x		;сделаем из x знаковое число
	sub	ax, 160		;x=160 - центр экрана считаем нулем
	mov	x, ax		;сохраним в переменной для загрузки в сопроцессор
	fild	x		;грузим в сопроцессор
	fdiv	coef		;делим на коэффициент coef точек = 1
	fmul	n		;x * n
	fldpi			;пи
	fmul	m		;пи * m
	faddp			;x * n + пи * m
	fcos			;cos(x * n + пи * m)
	fmul	coef		;масштабируем: умножаем на коэффициент coef:1
	fistp	x		;преобразуем в целое
	mov	ax, 100		;100 - центр экрана по вертикали
	sub	ax, x		;ax - экранная координата по вертикали
	ret
fun	endp

;рисует график, последовательно соединяя точки отрезками
;параметры:
;xmin - левая экранная координата графика
;xmax - правая экранная координата графика
;pFun - адрес функции, вычисляющей экранную координату по вертикали
;col  - цвет линий
Graph	proc	xmin:word, xmax:word, pFun:word, col:word
Graph_loop:			;цикл рисования отрезков
	mov	ax, pFun	;адрес функции
	call	ax, xmin	;считаем y первой точки
	mov	cx, ax		;сохраним в cx

	mov	ax, xmin	;найдем x соседней справа точки
	inc	ax
	mov	si, ax		;сохраним в sі
	cmp	ax, xmax	;проверим, дошли и до правого края
	ja	Graph_ret

	mov	ax, pFun	;адрес функции
	call	ax, si		;ax = y второй точки

;рисуем линию (xmin, cx)-(si,ax) цветом col
	call	line, xmin, cx, si, ax, col
	mov	xmin, si	;готовим xmin для следующего шага
	jmp	Graph_loop
Graph_ret:
	ret
Graph	endp

;рисуем линию (x1,y1)-(x2,y2) цветом color
Line	proc	uses di bx, x1:word, y1:word, x2:word, y2:word, color:byte
local	i:word, 	\	;для работы со сопроцессором
	delta_x:word,	\	;длина проекции на ось абсцисс
	delta_y:word,	\	;длина проекции на ось ординат
	incx:word,	\	;приращение по X
	incy:word		;приращение по Y

;определим длину проекции на ось абсцисс и шаг по оси X
	mov	ax, x2
	sub	ax, x1		;ax=x2-x1;

;определим шаг по X (+1 если вперед, -1 если назад, 0 если не меняется)
	mov	incx, 0		;пусть incx=0
	test	ax, ax		;ax=delta_x 
	jz	set_delta_x	;не меняется
	jg	set_x_1		;вперед?
	dec	incx		;назад, значит incx=-1
	neg	ax		;найдем ax=abs(delta_x)
	jmp	set_delta_x	;на сохранение
set_x_1:
	inc	incx		;вперед, значит incx=1;
set_delta_x:
	mov	delta_x, ax	;delta_x = abs(x2-x1)

;определим длину проекции на ось ординат и шаг по оси Y
	mov	ax, y2
	sub	ax, y1		;ax=y2-y1;

;определим шаг по Y (+1 если вперед, -1 если назад, 0 если не меняется)
	mov	incy, 0		;пусть incy=0
	test	ax, ax		;ax=delta_y
	jz	set_delta_y	;не меняется
	jg	set_y_1		;вперед?
	dec	incy		;назад, значит incy=-1
	neg	ax		;найдем ax==abs(delta_y)
	jmp	set_delta_y	;на сохранение
set_y_1:
	inc	incy		;вперед, значит incy=1;
set_delta_y:
	mov	delta_y, ax	;delta_y=abs(y2-y1)
	
;определим большее из проекций как основное напрвление
	cmp	ax, delta_x	;ax=delta_y
	jge	from_y		;y будет основным
	cmp	delta_x, 0	;проверим, чтобы не было delta_x=0 (для точки),
	jz	Line_ret	; иначе будет деление на 0
;delta_x>delta_y && delta_x!=0
;основное направление - по оси X
	fild	delta_y
	fidiv	delta_x		;st=k=(float)(delta_y/delta_x)

;for (int i=0;i<delta_x;i++)
	xor	cx, cx		;cx=i
	jmp	cmp_i_x		;на проверку i<delta_x 
x_loop:				;тело цикла
	mov	i, cx		;запишем переменную цикла в память (для сопроцессора)
	fld	st		;st=st(1)=k
	fimul	i		;st=k*i
	fimul	incy		;st=incy*k*i
	call	floor		;округлим до целого в большую сторону
	fistp	i		;сохраним в переменной
	mov	ax, i		;относительный номер строки на экране
	add	ax, y1		;добавим до ординаты начальной точки
	mov	dx, 320		;получим индекс начала строки экрана в сегменте экрана
	imul	dx		; для этого умножим на длину в байтах одной стоки
	mov	bx, ax		;сохраним bx=y=(y1+floor(incy*k*i))*320
				;посчитаем X
	mov	ax, incx	;X меняется ровно на шаг приращения,
	imul	cx		; умноженному на индекс точки
	add	ax, x1		;добавим абциссу начальной точки ax=x=x1+incx*i

	add	ax, bx		;сложим с индексом начала строки
	mov	di, ax		;будем адресовать через di

	mov	al, color	;цвет точки
	mov	es:[di], al	;рисуем!

	inc	cx		;на следующую точку
cmp_i_x:
	cmp	cx, delta_x	;дошли до конца?
	jl	x_loop
	jmp	Line_ret	;на выход
 
from_y:				;вдоль оси Y
	fild	delta_x
	fidiv	delta_y		;st=k=(float)(delta_x/delta_y)

;for (int i=0;i<delta_y;i++)
	xor	cx, cx		;cx=i
	jmp	cmp_i_y 	;на проверку i<delta_y 
y_loop:				;тело цикла
	mov	ax, incy	;Y меняется ровно на шаг приращения,
	imul	cx		; умноженному на индекс точки
	add	ax, y1		;добавим абциссу начальной точки ax=y=y1+incy*i
	mov	dx, 320		;получим индекс начала строки экрана в сегменте экрана
	imul	dx		; для этого умножим на длину в байтах одной стоки		
	mov	bx, ax		;сохраним bx=y=(y1+incy*i)*320
				;посчитаем X
	mov	i, cx		;запишем переменную цикла в память (для сопроцессора)
	fld	st		;st=st(1)=k
	fimul	i		;st=k*i
	fimul	incx		;st=incx*k*i
	call	floor		;округлим до целого в большую сторону
	fistp	i		;сохраним в переменной
	mov	ax, i		;относительный номер строки на экране
	add	ax, x1		;ax=x=x1+floor(incx*k*i)

	add	ax, bx		;сложим с индексом начала строки
	mov	di, ax		;будем адресовать через di

	mov	al, color	;цвет точки
	mov	es:[di], al	;рисуем!

	inc	cx		;на следующую точку
cmp_i_y:
	cmp	cx, delta_y	;дошли до конца?
	jl	y_loop
Line_ret:
	fistp	i		;удалим из сопроцессора k
	ret
Line	endp

;округление до целого в большую сторону
;округление по умолчанию, до ближайщего, не устраивает
floor	proc
local	CtrlWordOld:word, CtrlWordNew:word
	fstcw	CtrlWordOld		;сохраним управляющее слово
	fclex				;сбросим исключения
	mov	CtrlWordNew, 0763h	;установим необходимое значение управляющего слова
	fldcw	CtrlWordNew		;загружаем управляющее слово
	frndint				;округляем st до целого
	fclex				;сбросим исключения
	fldcw	CtrlWordOld		;восстановим старое управляющее слово
	ret
floor	endp

;выводим на экран f(x)=cos(n*x+m*Pi)
;параметр textcolor - цвет текста
PrFun	proc	textcolor:word
	mov	bx, textcolor		;цвет
	lea	si, Pr1			;первая часть текста
	call	PrText
	lea	si, NText		;N в виде строки
	call	PrText
	lea	si, Pr2			;вторая часть текста
	call	PrText
	lea	si, MText		;M в виде строки
	call	PrText
	lea	si, Pr3			;третья часть текста
	call	PrText
	ret
PrFun	endp

;выводим строку по адресу [si], строка должна заканчиваться 0dh
PrText	proc
	lodsb
	cmp	al, 0dh
	je	PrRet
	mov	ah, 0eh
	int	10h
	jmp	PrText
PrRet:
	ret
PrText	endp

	.data
n	dd	0			;исходные коэффициенты
m	dd	0
coef	dd	25.			;коэффициент для масштабирования на экране
sN	db	'N= $'
sM	db	0dh,0ah,'M= $'
Pr1	db	'f(x)=cos(',0dh
Pr2	db	'*x+',0dh
Pr3	db	'*Pi)',0dh
NMax	db	6
	db	0
NText	db	7 dup (0)
MMax	db	6
	db	0
MText	db	7 dup (0)
	END