Здравствуйте, Yankov Dmitry!
Предлагаю такую программу.
Для заполнения матрицы использовал несложный генератор псевдослучайных чисел.
Для его инициализации - системное время.
Если что непонятно, спрашивайте.
[code h=200]
.model small

N equ 5 ;размерность матрицы
.data
seed dw ? ;очередное псевдослучайное число
matrix dw 5*5 dup (?) ;матрица 5*5 слов

.code
start:
mov ax, @data
mov ds, ax
mov es, ax

call randInit ;инициируем последовательность псевдослучайных чисел

;заполним матрицу псевдослучайными числами 0-99
lea di, matrix ;адрес
mov cx, N*N ;количество
formMatrixLoop:
call rand ;получаем число
stosw ;пишем в матрицу
loop formMatrixLoop ;по всем элементам матрицы

;запишем главную диагональ в обратном порядке
xor si, si ;смещение элемента левого верхнего угла матрицы (самого первого)
mov di, 2*(N*N-1) ;смещение элемента правого нижнего угла матрицы (самого последнего)
ChangeLoop: ;по элементам главной диагонали
cmp si, di ;меняем, пока первый индекс меньше второго
jae ChangeEnd ;все сделано - на выход
mov ax, matrix[si] ;меняем местами matrix[si] и matrix[di]
xchg ax, matrix[di]
xchg ax, matrix[si]
add si, 2*(N+1) ;смещаем на следующий диагональный
sub di, 2*(N+1) ;смещаем на предыдущий диагональный
jmp ChangeLoop ;на следующий обмен
ChangeEnd:

mov ax, 4c00h
int 21h

;инициализация последовательности псевдослучайных чисел
randInit proc
mov ah, 2ch ;запрашиваем текущее время
int 21h ;получим: ch - секунды, cl - сотые секунды, dh - часы, dl - минуты
xor cx, dx ;сделаем более "случайным"
xchg ch, cl ;и чтобы младший байт шел первым
mov seed, cx ;сохраним
ret
randInit endp

;получение очередного псевдослучайного числа в диапозоне 0-99
rand proc near
mov ax, seed ;предыдущее случайное число
mov dx, 8E45h ;возьмем вот такое число
mul dx ;и умножим на него
inc ax ;чтобы исключить "зацикливание" на нуле
mov seed, ax ;сохраним
xor dx, dx ;получим число в диапозоне 0-99
mov bx, 100 ;для этого разделим на 100
div bx
mov ax, dx ;и возьмем остаток от деления
ret
rand endp
end start
[/code]