Здравствуйте, JohnyWayne!
Вот и программа. Файловые операции проверяются на ошибки. Будет непонятно - спрашивайте.

[code h=200]
.model small
.code
start:
mov ax, @data
mov ds, ax
mov es, ax

mov ss, ax ;сделаем стек вверху сегмента данных
mov sp, 0

lea dx, sGetIn ;строка приглашения 'Enter input file name:'
call GetName ;ds:dx = адресу имени входного файла

;откроем входной файл
mov ax, 3d00h ;открываем файл на чтение
int 21h
jc OpenError ;ошибка?
mov bx, ax ;сохраним описатель файла в bx для дальнейшей работы

;прочитаем
lea dx, buffer ;адрес буфера
mov cx, 0fc00h ;максимальное число байт (63k), которое мы будем читать
mov ah, 3fh ;функция чтения
int 21h
jc ReadError ;ошибка?
mov si, ax ;сохраним длину файла в si

mov ah, 3eh ;закроем входной файл
int 21h

;проверим на длину
cmp si, 10 ;длина файла < 10?
jb SizeError

;введем имя выходного файла
lea dx, sGetOut ;строка приглашения 'Enter output file name:'
call GetName ;ds:dx = адресу выходного файла

;создадим выходной файл
xor cx, cx ;без атрибутов
mov ah, 3ch ;функ
int 21h
jc CreateError ;ошибка?
mov bx, ax ;сохраним описатель файла в bx для дальнейшей работы

lea dx, buffer+10 ;адрес буфера, смещенный на 10
lea cx, [si-10] ;cx = длине файла - 10
mov ah, 40h ;функция записи
int 21h
jc WriteError ;ошибка

lea dx, sCopied ;выведем 'Data copied'

MessageWithClose: ;выводим сообщение
mov ah, 9
int 21h

CloseFile: ;закрываем файл
mov ah, 3eh
int 21h

PressAny:
lea dx, sAny ;выведем 'Press any key'
mov ah, 9
int 21h

mov ah, 0 ; ждем нажатие на клавишу
int 16h

mov ax,4c00h ; конец работы
int 21h

;обработка ошибок
OpenError: ;ошибка открытия (файл или не найден, или занят)
lea dx, sOpenErr
jmp MessageWithoutClose ;сообщение без закрытия файла
ReadError: ;ошибка чтения
lea dx, sReadErr
jmp MessageWithClose ;сообщение с закрытием файла
SizeError: ;ошибка размера файла
lea dx, sSizeErr
jmp MessageWithoutClose ;сообщение без закрытия файла
CreateError: ;ошибка создания выходного файла
lea dx, sCreateErr
MessageWithoutClose: ;сообщение
mov ah, 9
int 21h
jmp PressAny ;на вывод 'Press any key'
WriteError: ;ошибка записи
lea dx, sWriteErr
jmp MessageWithClose ;сообщение с закрытием файла

;Подпрограмма ввода имени файла
;на входе: ds:dx - адрес сообщения
;на выходе: ds:dx - адрес имени
GetName proc
mov ah, 9 ;выведем приглашение из dx:dx
int 21h

lea dx, buf ;введем строку
mov ah, 0ah
int 21h

xor bx, bx ;заменим последний код 0dh на 0
mov bl, len ;длина введенной строки
mov byte ptr string[bx], 0 ;пишем 0

lea dx, string ;возвращаем адрес имени
ret
GetName endp

.data

;строки сообщений
sGetIn db 0dh,0ah,'Enter input file name: $'
sGetOut db 0dh,0ah,'Enter output file name: $'
sCopied db 0dh,0ah,'Data copied$'
sAny db 0dh,0ah,'Press any key$'

sOpenErr db 0dh,0ah,'File open error!$'
sSizeErr db 0dh,0ah,'File < 10 bytes!$'
sReadErr db 0dh,0ah,'File read error!$'
sCreateErr db 0dh,0ah,'File creare error!$'
sWriteErr db 0dh,0ah,'File write error!$'

buf label byte ; буфер для приема строки с клавиатуры (по ф-и 0ah)
max db 128 ; максимальная длина строки
len db 0 ; реальная длина введенной строки
string db 128 dup (?) ; сама строка

buffer label byte ;буфер для чтения файла (размещаем за программой)

end start
[/code]