Здравствуйте, Петрович!

Предлагаю вариант скрипта, который сканирует наличие в текущем каталоге подкаталогов и удаляет в них файлы, подходящие под условие.
Для корректной работы программы имя подкаталога должно иметь вид "ЦЦдальшеимякаталога" , где ЦЦ - двузначное число, показывающее более скольки дней создания удалять файлы. Например в каталоге 03архив удалятся все файлы, созданные более 3 дней назад, а в каталоге 13почта удалятся более 13 дней назад. По умолчанию ( если программа не сможет понять первые два символа как число ) удалятся файлы старше 5 дней ( например в подкаталоге "неудалять5дней" ) .

Данный скрипт можно поместить в автозапуск и освобождать каталоги архивов при входе в систему.


ps. в ходе обсуждения в форуме был разработан улучшенный скрипт ( обрабатывает все вложенные подкаталоги ) , который и поместил в приложение. при проверке работоспособности скрипта необходимо учитывать, что при копировании файлов дата создания будет изменена на текущую и проверка по дате создания не сработает правильно. при переносе дата создания не изменяется. либо можно проверять по дате последней модификации.

С уважением.

Приложение:
option explicit
'чтобы каждый раз не создавать объект, определяем как глобальную переменную
public fso

'а это локальные переменные, которые используются только в следующих четырех командах
dim dso
dim WshShell
dim tekkatalog

'Создаем объект FileSystemObject
Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
'Создаем объект WshShell
Set WshShell = WScript.CreateObject("WScript.Shell")
'определяем текущий каталог, из которого запущен скрипт
tekkatalog=replace(WScript.ScriptFullName,"" & WScript.scriptname,"")
'можно явно указать, с какого каталога начинать поиск, например командой
'tekkatalog="D:\Temp\archive"

'вызываем функцию, а в параметрах указываем основной каталог, с которого начинаем поиск, и дни по-умолчанию,
'которые будут использоваться для проверки, если в имени подкаталога явно не указано иное либо
'нет данных из родительского каталога
call subdirr(tekkatalog,5)
'ну вот и вся основная процедура. далее идет выход из скрипта и останов


'вот сама рекурсия. входящие параметры - путь к подкаталогу в виде строки и количество дней для проверки
function subdirr(folder,dni)
'определяем переменные, которые будут использоваться в этой функции
dim ddso
dim subkatalog
dim tempfile
dim den

'получаем список подкаталогов
set ddso=fso.getfolder(folder)

for each subkatalog in ddso.subfolders
'сохраняем условие отбора для дальнейшего использования и используем другую переменную
den=dni
if isnumeric(mid(subkatalog.name,1,2)) then
'если два первых символа названия подкаталога можно преобразовать в число,
'то используем это значение, иначе оставляем входящий параметр
den=clng(mid(subkatalog.name,1,2))
end if
'вызываем рекурсией эту же функцию для проверки всех подкаталогов
call subdirr(subkatalog.parentfolder & "" & subkatalog.name,den)
next

'если больше подкаталогов нет, то работаем с файлами
set ddso=fso.getfolder(folder)
for each tempfile in ddso.files
'получаем список файлов в подкаталоге и проверяем условие
'если первый каталог указан явно, то проверку на имя файла можно не делать
'если же скрипт вызывается в текущем каталоге и начинает работу с него, то оставить второе условие
'чтобы случайно не удалить саму программу. соответственно если в подкаталогах случайно
'окажется файл с таким же именем, то он тоже удален не будет
if tempfile.datecreated<dateadd("d",-dni,Now) and tempfile.name<>"del_rekurs.vbs" then
'кроме даты создания ( DateCreated ) можно сравнивать по дате модификации ( DateLastModified ) или доступа ( DateLastAccess )
'удаляем файлы, подходящие под условие
fso.deletefile (tempfile.parentfolder & "" & tempfile.name),true
end if
next
end function

Здравствуйте, Петрович!
Предлагаю два варианта решения: с помощью .bat - файла и скрипта .vbs

В .bat-файле основная трудность - работа с датой. Я предполагаю, что в системе дата имеет формат dd.mm.yyyy.
Идея решения - преобразовать даты в числа вида yyyymmdd, и их уже сравнивать.
Построение командного файла описана в комментариях по тексту.
Для того, чтобы вычислить дату, отстоящую от текущей на заданное кол-во дней заимствовал готовую процедуру (см здесь или здесь ).
Далее при просмотре файлов в указанной директории командой For
выделяю дату для каждого файла, преобразовываю её к виду, пригодному для сравнения, и более старые файлы удаляю.


В vbs-cкрипте с сравнением дат нет проблем, аналог bat-файла предоставляю. Редкий случай - vbs-скрипт получился даже короче bat.
В мини-форуме приведен первый вариант моего скрипта, там вместо последовательного вызова процедуры исходные данные записываются в массив. Что удобнее- дело вкуса. Мне более по нраву последний вариант. Если понадобится, можно сделать и с подкаталогами. Кстати, в bat-файле это можно сделать проще.