Здравствуйте, АлексАлексей!

Смотрите приложение.
Реализован волновой алгоритм поиска хода в лабиринте. При вычислении возможного хода в массиве POLE отмечается положительным значением(препятствия имеют отрицательные числа) номер возможного хода, в массиве А- запоминается сам ход. Когда массив будет заполнен, находится максимальное значение и с помощью массива А, находится начальное направление движения шара. Маркер препятствия и шарик не могут перейти на уже занятое поле, но маркер может стоять на последнем выставленом препятствии.

Шарик иногда "топчется" на месте, это из-за того, что максимальное значение расчитывается при каждом ходе и иногда меняет свое положение.
ps:вопросы задавайте в мини-форум.
Удачи!

Приложение:
uses crt,graphABC;
const
x_Max=10;{максимальный размер поля по Х}
y_Max=10;{максимальный размер поля по У}
x_d=20;{размер позиции по Х}
y_d=20;{размер позиции по У}
TimeOut=500;{служебная задержка}
r_Obstacle=5;{радиус маркера препятствия}
r_Ball=8;{радиус шара}
type
tMass=array[1..x_Max,1..y_Max]of integer;
var
Pole:tMass;
x_Obstacle,y_Obstacle:integer;{координаты маркера препятствия}
x_Ball,y_Ball:integer;{координаты шара}
c:char;
function Check(a,b:integer):boolean;
begin{check}
Check:=(a>0)and(a<=b);{условие контроля}
end;{check}
function Check_All(a,b,c,d:integer):boolean;
begin{check_all}
Check_All:=Check(a+c,x_Max)and{проверяем координату Х}
Check(b+d,y_Max)and{проверяем координату У}
(Pole[a+c,b+d]=0);{проверяем наличие препятствий}
end;{check_all}
Procedure Set_A(a,b:integer);
begin{set_a}
if Pole[x_Ball,y_Ball]=0 then Pole[x_Ball,y_Ball]:=-2;{устанавливаем положение шара}
if Check_All(x_Obstacle,y_Obstacle,a,b)then
begin{if}
x_Obstacle:=x_Obstacle+a;{изменяем координату}
y_Obstacle:=y_Obstacle+b;{изменяем координату}
end;{if}
if Pole[x_Ball,y_Ball]=-2 then Pole[x_Ball,y_Ball]:=0;{освобождаем поле занятое шаром}
end;{set_a}
procedure Set_B;
var
a:tMass;
c:boolean;
i,j,n,z:integer;
begin{set_b}
if Pole[x_Obstacle,y_Obstacle]=0 then Pole[x_Obstacle,y_Obstacle]:=-3;{устанавилваем позицию маркера}
for i:=1 to x_Max do for j:=1 to y_Max do a[i,j]:=0;{сбрасываем таблицу предков :-)}
Pole[x_Ball,y_Ball]:=1;{текущее положение шара}
z:=0;{текущий уровень}
repeat
inc(z);{следующий уровень}
c:=true;{параметр выхода}
for i:=1 to x_Max do for j:=1 to y_Max do{в цикле перебираем все элементы}
if Pole[i,j]=z then{равно текущему работаем}
for n:=0 to 8 do{все возможные направления движения}
if(abs((n mod 3)-1)<>abs((n div 3)-1))and{исключаем диагонали}
Check_All(i,j,(n mod 3)-1,(n div 3)-1)then{контролируем поле}
begin{if}
a[i+(n mod 3)-1,j+(n div 3)-1]:=n;{ход, который привел к этому напрвлению}
Pole[i+(n mod 3)-1,j+(n div 3)-1]:=z+1;{новый уровень}
c:=false;{сбрасываем параметр цикла}
end;{if}
until c;{если истина, значит больше возможных ходов нет}
n:=1;z:=1;{пока максимальное число ходов левый верхний элемент}
for i:=1 to x_Max do for j:=1 to y_Max do{вцикле проверяем все значения}
if Pole[i,j]>Pole[n,z] then{если больше запоминаем}
begin
n:=i;z:=j;{новое значение}
end;
i:=n;j:=z;{запоминаем координаты максимального значения}
repeat
n:=a[i,j];{ход который привел к этой точке}
i:=i+1-(n mod 3);{считаем координаты предков по Х}
j:=j+1-(n div 3);{считаем координаты предков по У}
until (i=x_Ball)and(j=y_Ball);
x_Ball:=x_Ball+(n mod 3)-1;{изменяем положение шара по Х}
y_Ball:=y_Ball+(n div 3)-1;{изменяем положение шара по У}
for i:=1 to x_Max do for j:=1 to y_Max do{в цикле}
if Pole[i,j]>0 then Pole[i,j]:=0;{убираем таблицу поиска}
if Pole[x_Obstacle,y_Obstacle]=-3 then Pole[x_Obstacle,y_Obstacle]:=0;{освобождаем позицию маркера}
end;{set_b}
procedure Show;
var
i,j:integer;
begin{show}
for i:=1 to x_Max do for j:=1 to y_Max do{показываем статус всех полей}
begin{for for}
if Pole[i,j]=0 then SetBrushColor(clMedGray){свободно}
else SetBrushColor(clGreen);{занято}
Rectangle(i*x_d,j*y_d,(i+1)*x_d,(j+1)*y_d);{рисуем}
end;{for for}
SetBrushColor(clSkyBlue);{показываем маркер препятствия - голубым}
Circle(x_Obstacle*x_d+(x_d div 2),y_Obstacle*y_d+(y_d div 2),r_Obstacle);
SetBrushColor(clBlue);{показываем шар - синим}
Circle(x_Ball*x_d+(x_d div 2),y_Ball*y_d+(y_d div 2),r_Ball);
end;{show}
begin{main}
SetWindowCaption('This my game');
for x_Ball:=1 to x_Max do for y_Ball:=1 to y_Max do Pole[x_Ball,y_Ball]:=0;{чистим рole}
x_Obstacle:=1;y_Obstacle:=1;{начальное положение маркера}
x_Ball:=5;y_Ball:=5;{начальное положение шара}
repeat
Show;{рисуем Экран}
delay(TimeOut);{задержка отображения}
if KeyPressed then{обрабатываем нажатие клавиши}
begin{if}
c:=ReadKey;{код клавиши}
if ord(c)=0 then c:=ReadKey;{исключаем нулевой(служебный) байт}
case c of
#80:Set_A(0,1);{устанавливаем новую координату}
#72:Set_A(0,-1);{устанавливаем новую координату}
#75:Set_A(1,0);{устанавливаем новую координату}
#77:Set_A(-1,0);{устанавливаем новую координату}
#13:Pole[x_Obstacle,y_Obstacle]:=-1;{устанавливаем маркер препятствия}
end;{case}
end;{if}
Set_B;{устанавливаем новую координату шара}
until c=#27;{press ESC}
end.{main}