Здравствуйте, Aleksandrkib.
Примерно так. Достаточно прокомментировано, если что осталось непонятно, спрашивайте в мини-форуме
[code h=200]
.model small
.data
sNum1 db 'Enter first number: $' ;Строка приглашения для ввода первого числа
sNum2 db 'Enter second number: $' ;Строка приглашения для ввода второго числа
sSum db 'Result = ' ;Строка вывода результата
sNum db '00$' ;Сюда вставим число-сумму введенных чисел

.code
.286 ;чтобы использовать shr al, 4
.startup ;точка входа
;вводим первое число
lea dx, sNum1 ;строка приглашения
call GetNumber ;в al однобайтное BCD число
mov bh, al ;сохраним в bh
;вводим второе число
lea dx, sNum2 ;строка приглашения
call GetNumber ;в al однобайтное BCD число

add al, bh ;сложим с первым
daa ;делаем коррекцию!
;в al корректное BCD число
;выведем сообщение, для этого сформируем двубайтное символьное число
mov ah, al ;обработам и старший полубайт, и младший
shr al, 4 ;старший десятичный разряд в младшем полубайте al
and ah, 0fh ;младший десятичный разряд в младшем полубайте ah
or ax, '00' ;числа - в символы
mov word ptr sNum, ax ;запишем двубайтное число в строку результата

lea dx, sSum ;выведем
mov ah, 9
int 21h

.exit 0

;ввод однобайтного BCD числа
;результат - в al
GetNumber proc
mov ah, 9 ;подсказка
int 21h

mov bl, 0 ;здесь будем формировать BCD число
mov cx, 2 ;вводим максимум две цифры
GetLoop:
mov ah, 1 ;вводим символ
int 21h
cmp al, 0dh ;по Enter-у заканчиваем ввод досрочно
je GetNumRet
cmp al, '0' ;проверим на цифру
jb GetLoop
cmp al, '9'
ja GetLoop
and al, 0fh ;получаем из символа число 0-9
shl bl, 4 ;старый младший десятичный разряд становится старшим
or bl, al ;вставляем новый младший разряд
loop GetLoop ;вводим максимум две цифры

GetNumRet: ;перейдем на новую строку
mov ah, 2
mov dl, 0dh
int 21h
mov dl, 0ah
int 21h
mov al, bl ;результат в al
ret
GetNumber endp

end
[/code]