Здравствуйте, Яруллина Ирина Булатовна.

Вот возможное решение.


Приложение:
{
В системе регистрации заявок сервисного центра
составляется список заявок в зависимости от
приоритета отправителя (если клиент постоянный
и важный приоритет - 0, если постоянный,
но можно ненадолго отложить - 1 и т.д.).

Сформировать список заявок, начиная с наивысшего
приоритета и вывести его на экран.
}

Program Requests;

Type
PRequestList = ^TRequest; { список заявок }
TRequest = Record { описание элемента списка}
req_text : string; { текст заявки }
req_rank : Byte; { приоритет заявки }

next : PRequestList; { следующая заявка в списке }
end;

TRequestFile = file of TRequest; { типизированный файл для хранения списка заявок }

Var
p : PRequestList; { указатель на список заявок }

s : string; { строка - используется для ввода данных пользователя }

{ Процедура аварийного завершения программы с описанием причины }
Procedure Fatal (msg : string);
begin
writeln;
writeln ('Ошибка: ', msg);
Halt (1);
end;

{ Процедура сохранения списка в файле }
Procedure SaveList (fname : string; p : PRequestList);
var
f : TRequestFile; { файловая переменная }
q : PRequestList; { указатель на элемент списка }

begin
{ Создание файла с обработкой ошибок }
{$I-}
Assign (f, fname); Rewrite (f);
{$I+}
if IOResult <> 0 then Fatal ('Не могу создать файл ' + fname + '!');

q := p; { начинаем обрабатывать список сначала }
while q <> nil do { пока есть элементы }
begin
write (f, q^); { записываем элемент в файл }
q := q^.next; { переходим к следующему элементу списка }
end;

Close (f); { закрыть файл }
end;

{ процедура считывания списка из файла }
Function LoadList (fname : string) : PRequestList;
var
f : TRequestFile; { файловая переменная }
p : PRequestList; { указатель на начало списка (точнее, элемент, предшествующий первому элементу списка) }
q : PRequestList; { указатель на элемент списка }

begin
{ Открытие файла с обработкой ошибок }
{$I-}
Assign (f, fname); Reset (f);
{$I+}
if IOResult <> 0 then Fatal ('Не могу открыть файл ' + fname + '!');

New (q); { создаем временный элемент списка }
q^.next := nil; { устанавливаем признак конца списка }
p := q; { сохраняем полученный указатель }
while not eof (f) do { считываем записи до конца файла }
begin
New (q^.next); { создаем новый элемент }
read (f, q^.next^); { считываем значение элемента из файла }
q^.next^.next := nil; { корректируем указатель на следующий элемент }
q := q^.next; { переходим к следующему элементу }
end;
LoadList := p^.next; { реальный список начинается со второго элемента }
Dispose (p); { удаляем временный элемент }

Close (f); { закрываем файл }
end;

{ Процедура очистки экрана (вместо использования аналогичной процедуры из модуля Crt) }
Procedure ClrScr; assembler;
asm
mov ax, 3
int 10h
end;

{ Процедура вывода списка согласно приоритетам }
Procedure PrintList (p : PRequestList);
var
q : PRequestList; { указатель на элемент списка }
cur_rank : Byte; { текущее значение приоритета }
first : Boolean; { флаг обработки начального элемента }
req_num : Byte; { количество выведенных заявок на текущем экране }

{ Локальная процедура вывода информации о приоритете }
procedure PrintRank (r : Byte);
begin
ClrScr;
writeln ('Заявки с приоритетом ', cur_rank);
writeln ('------------------------');
req_num := 0;
end;

{ Локальная процедура вывода подсказки для пользователя после заполнения экрана }
procedure PrintQuery;
begin
writeln;
write ('Нажмите Enter...');
readln;
end;

begin
q := p; { начинаем обработку с начала списка }
first := true; { устанавливаем признак начального элемента }
req_num := 0; { количество отображенных заявок - 0 }

while q <> nil do { пока элементы не закончились }
begin
{ если элемент начальный или произошла смена приоритета }
if first or (cur_rank <> q^.req_rank) then begin
if req_num <> 0 then PrintQuery; { если были выведены элементы - ждем реакцию пользователя }
cur_rank := q^.req_rank; { устанавливаем новый приоритет }
PrintRank (cur_rank); { выводим информацию о приоритете }
first := false; { сбрасываем признак начального элемента }
end;

writeln (q^.req_text); { выводим текст заявки }
Inc (req_num); { увеличиваем число выведенных заявок }
if req_num = 20 then begin { если вывели 21 заявку - ждем реакцию пользователя }
PrintQuery; { реакция }
PrintRank (cur_rank); { выводим информацию о приоритете }
end;

q := q^.next; { переходим к следующему элементу }
end;

if req_num <> 0 then PrintQuery; { если были выведены элементы - ждем реакцию пользователя }
end;

{ Процедура добавления заявки в список с учетом приоритета }
Procedure InsertIntoList (var p : PRequestList; r : PRequestList);
var
q : PRequestList; { элемент списка }

begin
q := p; { перебираем элементы с начала списка}
while q^.next <> nil do { пока список не пуст}
begin
{ если текущий элемент имеет такой же приоритет, как и у добавляемой заявки }
if q^.next^.req_rank = r^.req_rank then begin
{ вставим элемент перед текущим}
r^.next := q^.next;
q^.next := r;
break; { закончим просмотр списка }
end
{ если текущий элемент имеет более низкий приоритет, нежели у добавляемой заявки }
else if r^.req_rank < q^.next^.req_rank then begin
{ добавим элемент перед текущим - получаем список заявок, отсортированных по приоритетам }
r^.next := q^.next;
q^.next := r;
break; { закончим просмотр списка }
end;

q := q^.next; { перейдем к следующему элементу }
end;

{ если просмотрели весь список и не смогли вставить заявку - }
{ значит, у данной заявки новый приоритет, причем он самый низкий }
{ поэтому добавляем заявку в конец списка }
if q^.next = nil then q^.next := r;
end;

{ Функция ввода заявки пользователем }
Function InputRequest : PRequestList;
var
r : PRequestList; { указатель на заявку }

begin
New (r); { создаем заявку }
r^.next := nil; { следующего элемента нет}

{ запрос ввода текста заявки }
write ('Введите текст заявки (или введите "." для окончания ввода): '); readln (r^.req_text);
if r^.req_text = '.' then begin
Dispose (r); { удалить заявку }
InputRequest := nil; { возвратить нулевой указатель }
exit;
end;

{ запрос ввода приоритета заявки }
write ('Введите приоритет заявки: '); readln (r^.req_rank);
InputRequest := r; { возвратить заявку }
end;

{ Функция ручного ввода списка заявок }
Function InputList : PRequestList;
var
p : PRequestList; { указатель на список }
r : PRequestList; { указатель на заявку }

begin
ClrScr; { очистить экран и вывести заголовок }
writeln ('Ручной ввод заявок');
writeln;

New (p); { создать список }
p^.next := nil; { только временный элемент }

Repeat
r := InputRequest; { ввод заявки пользователем }
if r = nil then break { выйти из цикла при окончании ввода }
else InsertIntoList (p, r); { добавить заявку в список в соответствии с приоритетом }
Until false; { повторить ввод заявки }

InputList := p^.next; { возвратить список без учета временного элемента }
Dispose (p); { удалить временный элемент }
end;

{ Функция получения списка заявок }
Function GetList : PRequestList;
var
s : string;

begin
ClrScr; { очистить экран }

{ запрос информации от пользователя }
write ('Укажите имя файла со списком заявок (или введите "-" для ручного ввода): '); readln (s);

{ сформировать список заявок либо с помощью ручного ввода, либо путем загрузки из файла }
if s = '-' then GetList := InputList else GetList := LoadList (s);
end;

{ Процедура добавления новых заявок в список }
Procedure AddRequests (var p : PRequestList);
var
r : PRequestList; { указатель на заявку }
t : PRequestList; { указатель на список заявок }

begin
{ запрос информации от пользователя }
write ('Хотите добавить заявки? '); readln (s);
if s [1] in ['Y', 'y', 'Д', 'д'] then begin
New (t); { сформировать временный элемент }
t^.next := p; { перед реальным списком }

Repeat
r := InputRequest; { ввод заявки пользователем }
if r = nil then break; { выйти из цикла при окончании ввода }
InsertIntoList (t, r); { добавить заявку в список в соответствии с приоритетом }
Until false; { повторить ввод заявки }

p := t^.next; { откорректировать указатель на первый элемент списка }
Dispose (t); { удалить временный элемент }
end;
end;

{ Основная программа }
Begin
p := GetList; { получить список заявок }
PrintList (p); { вывести список на экран }

AddRequests (p); { добавить новые заявки }
PrintList (p); { вывести обновленный список }

{ предложить пользователю сохранить список в файле }
write ('Введите имя файла для сохранения списка заявок (или введите "-" если не хотите сохранять): ');
readln (s);
if s <> '-' then SaveList (s, p); { сохранить список в файле }
End.