Здравствуйте, Даниил Цветков.
Примерчик не из простых: активно используется сопроцессор, если он Вам не знаком, то придется туго.
Еще момент: в сопроцессоре нет команды возведения в степень, поэтому при вычислениях e^x+y и cos^5/3(x)
приходится прибегать сначала к логарифмированию, затем строить число масштабированием...
Параметры для нахождения b передаются через регистры, но только сопроцессора.
Рекомендую совместно с просмотром в отладчике того, как работает программа, считать на калькуляторе - помогает видеть, как идут вычисления


Приложение:
.386 ;необходимо для команды fcos
sseg segment stack "stack"
db 1024 dup (0)
sseg ends

dsegX segment use16 para public 'data'
x dd 1.5
dsegX ends

dsegY segment use16 para public 'data'
y dd 0.5
dsegY ends

dsegZ segment use16 para public 'data'
z dd 1.1
dsegZ ends

dseg segment use16 para public 'data'
a dd ?
b dd ?
;константы
c8 dd 8.
c85 dd 8.5e-3
c4 dd 0.0004
c5 dd 5.
c3 dd 3.
dseg ends

;в st должно находиться xlog[2]y
POWER MACRO
fld st ;x*log[2]e->st(1)
frndint ;округляем st до целого
fsub st(1),st ;st(1)-=st
fxch ;st(1)<->st
f2xm1 ;st=(2 в степени st) - 1
fld1 ;1->st
fadd ;st+=1
fscale ;exp = st * (2 в степени st(1))
fstp st(1) ;чтобы убрать значение из st(1)
ENDM

;в st cos(x), который возводим в степень 5/3
POWERST MACRO
fld c5
fdiv c3 ;5/3
fxch
fyl2x ;st=st(1)*log[2]st
POWER ;находим cos(x)^(5/3)
ENDM

;e^st + 1/8
;st = x + y
EXP18 MACRO
fldl2e ;log(осн 2)e->st
fmulp ;st(1)*log(осн 2)e->st
POWER ;находим e^(x+y)
fld1 ;1
fdiv c8 ;1/8
faddp ;st = 1/8 + exp(x+y)
ENDM

;берем x и y из памяти, ищем x+y и вычисляем 1/8 + exp(x+y)
EXY18M MACRO xoff,yoff
les bx,xoff
fld dword ptr es:[bx] ;x->st
les bx,yoff
fadd dword ptr es:[bx] ;x+y->st
EXP18
ENDM

cseg segment para use16 public 'code'
assume cs:cseg, ss:sseg, ds:dseg
start:
mov ax,sseg
mov ss,ax
mov ax,dseg
mov ds,ax

push dsegZ ;в стек длинные адреса z
push offset z
push dsegY
push offset y ;y
push dsegX
push offset x ;x
call calc_a ;получаем в st ответ
fstp a ; и сохраняем его в переменной

;загружаем переменные в стек сопроцессора
mov ax,dsegZ ;сегмент для z
mov es,ax
fld dword ptr es:[z] ;z->st(2)
mov ax,dsegY ;сегмент для y
mov es,ax
fld dword ptr es:[y] ;y->st(1)
mov ax,dsegX ;сегмент для x
mov es,ax
fld dword ptr es:[x] ;x->st
call calc_b ;получаем в st ответ
fstp b ; и сохраняем его в переменной

mov ax,3c00h
int 21h

par_x equ [bp+4] ;для адресации в стеке
par_y equ [bp+8]
par_z equ [bp+12]

calc_a proc
push bp
mov bp,sp

les bx, dword ptr par_x ;длинный указатель на x
fld dword ptr es:[bx] ;st = x
fcos ;st = cos(x)
POWERST ;st = cos(x)^(5/3)
fmul c4 ;st = 0.0004 * cos(x)^(5/3)
les bx, dword ptr par_z ;длинный указатель на z
fld dword ptr es:[bx] ;st = z
fmul c85 ;st = z * 8.5*10^-3
fsubp ;st = 0.0004 * cos(x)^(5/3) - z * 8.5*10^-3
EXY18M par_x,par_y ;st = exp(x+y) + 1/8
fdivp ;st = st(1) / st
pop bp
ret 12
calc_a endp

calc_b proc
fld st ;x
fadd st,st(2) ;x+y
EXP18 ;exp(x+y)+1/8
fld st(3) ;z
fmul st,st(4) ;z*z
fld st(3) ;y
fsub c5 ;y-5
fdivp ;z*z/(y-5)
fsubp ;exp(x+y)+1/8 - z*z/(y-5)
faddp st(1) ;exp(x+y)+1/8 - z*z/(y-5) + x
fstp st(1) ;уберем из стека y и z
fstp st(1)
ret
calc_b endp

cseg ends
end start